NT. Nomenclatura de tabla.

Cuando convertimos un rango de datos (lista) en una tabla estamos agregando una estructura a ese rango que facilitará su manejo. Entre otras ventajas:

- - Permite referenciar los datos (filas, columnas) de forma más clara. En lugar de utilizar notación de rango para referirnos a filas, columnas, etc. podremos utilizar nombres estructurados.
  - Los datos se actualizan automáticamente. Así, las funciones que utilizan nombres estructurados en lugar de rangos no tendrán que ser actualizadas. Por ejemplo, tenemos la siguiente lista de datos.

Si queremos sumar la columna Importe utilizaríamos:

=SUMA(I2:I15)

Si hemos convertido el rango en una tabla llamada Datos, utilizaremos:

=SUMA(Datos[Importe])

La notación de esta segunda forma es más clara. Además, si añadimos cinco nuevos registros y queremos actualizar las sumas, en la notación clásica de rango tendremos que modificar a =SUMA(I2:I20), mientras que en la notación tabla no será necesario, los nuevos datos se incorporan a la tabla y la función =SUMA(Datos[Importe]) se actualiza de forma automática.

- - Las columna que contienen fórmulas se expanden automáticamente al añadir nuevas filas de datos (registros).

NT.1 Tablas.

Vídeo: NT.1

Título: Tablas.

url: https://video.auan234.com/ex/es/tabla_datos

Libro de trabajo: tabla_datos_v.xlsx

NT.1.1 Convertir un rango en una tabla.

Es aconsejable que la lista tenga una fila de encabezados con los nombres de cada columna.

1. Seleccione una celda de la lista o la lista entera incluyendo fila de encabezados (si la tiene).

2. Vaya a Insertar / Tabla, en el cuadro de diálogo indique si la tabla tendrá fila de encabezados.

3. Clique sobre Aceptar.

Si al crear la tabla no ha indicado fila de encabezados Excel creará una con los nombres Columna1, Columna2, etc.

Ejemplo NT.1.1-1

Convertir un rango en tabla.

Abra el libro de trabajo tabla_datos.xlsx de la carpeta ejercicios.

Seleccione cualquier celda de la lista vaya a Insertar / Tabla. Cuando aparezca el diálogo Crear tabla, active la opción La tabla tiene encabezados.
Cambie el nombre de la tabla.

Con el cursor dentro de la tabla, vaya a Diseño de tabla y en Nombre de la tabla ponga Ventas.

NT.2 Nomenclaturas para trabajar con elementos de una tabla.

Vídeo: NT.2

Título: Nomenclatura de Tablas.

url: https://video.auan234.com/ex/es/tabla_datos_nom

Libro de trabajo: tabla_datos_v2.xlsx

Ejemplo NT.2-1

Ejemplos de nomenclatura tabla para referirse a datos, columnas, encabezados, celdas.

Abra el libro de trabajo tabla_datos.xlsx de la carpeta ejercicios. Si no ha realizado el Ejemplo NT.1.1-2 hágalo ahora. Vamos a ver las opciones que tenemos para referenciar diferentes elementos o partes de la tabla.

NT.2.1 Referenciar todos los datos.

=Nombre_Tabla[#Datos] o de forma abreviada =Nombre_Tabla

- - - - Vaya a celda M1 y teclee =Ventas[#Datos] o simplemente =Ventas.

NT.2.2 Referenciar nombres de campo o columna.

=Nombre_Tabla[#Encabezados]

- - - - Vaya a celda M1 y teclee =Ventas[#Encabezados]

NT.2.3 Referenciar la tabla entera (Encabezados y datos).

=Nombre_Tabla[#Todo].

- - - - Vaya a celda M1 y teclee =Ventas[#Todo]

NT.2.4 Referenciar una columna (solo datos).

=Nombre_Tabla[Nombre_Columna]

- - - - Vaya a la celda M1 y teclee =Ventas[Marca]

NT.2.5 Referenciar una columna (Encabezado y datos).

=Nombre_Tabla[[#Todo] ; [Nombre_Columna]]

- - - - Vaya a la celda M1 y teclee =Ventas[[#Todo] ; [Marca]]

NT.2.6 Referenciar columnas adjuntas (solo datos).

=Nombre_Tabla[[Nombre_Columna]:[Nombre_Columna]]

- - - - Vaya a la celda M1 y teclee =Ventas[[Modelo]:[Importe Comercial]]

NT.2.7 Referenciar columnas adjuntas (Encabezado y datos).

=Nombre_Tabla[[#Todo] ; [Nombre_Columna] : [Nombre_Columna]]

- - - - Vaya a la celda M1 y teclee =Ventas[[#Todo];[Modelo]:[Importe Comercial]]

NT.2.8 Referenciar celdas individuales de la tabla.

Construir una columna calculada (o no) e incorporarla a la tabla.

Cuando crea una nueva columna adjunta a la tabla, ésta pasa a incorporarse a la tabla.

Vaya a la celda I1 y teclee Importe. La columna se incorpora a la tabla.
En J2 ponga la fórmula siguiente. Utilice el método de selección de celdas.

=[@[Precio Venta]] - [@[Importe Comercial]]

La @ que precede al nombre de la columna significa el elemento que está en la misma fila. Observe que la fórmula se expande al resto de fila, si no es así clique sobre el botón Autorrelleno que aparece junto a la celda y active la opción Sobrescribir todas las celdas...

- - - - Vaya a la celda K2 y entre la misma fórmula con el método de selección de celdas. Observe que ahora estamos fuera de la tabla y en la fórmula se incluye el nombre de la tabla y se opera con los datos de la misma fila.

=Ventas[@[Precio Venta]] - Ventas[@[Importe Comercial]]

- - - - Vaya ahora a celda M5 y, con el método de selección de celdas, ponga la misma fórmula referenciando las celdas de la fila 2. La fórmula será

=F2-H2

En nomenclatura clásica. Estamos fuera de la tabla y referenciamos filas distintas de la fila donde ponemos la fórmula.

NT.2.9 Utilizar nomenclatura tabla en funciones.

Ejemplo NT.2.9-1

Nomenclatura tabla en funciones.

Inserte una nueva hoja de cálculo al libro de trabajo. Llámela Funciones.
Vaya a la celda A1 de la hoja Funciones y sume el Importe.

=SUMA(Ventas[Importe])

Vaya a la celda A2 de la hoja funciones y sume el Importe pero solo de los vehículos Marca ‘Acme’.

=SUMAR.SI(Ventas[Marca] ; "Acme" ; Ventas[Importe])

En A3, con la función BDSUMA sume el Importe de los registros cuya Ciudad sea ‘Avalon’, la Marca ‘Acme’ y el Precio Venta > 12000

o Vaya a la celda G1 y muestre los encabezados de la tabla Ventas

=Ventas[#Encabezados]

o En I2 ponga Avalon, en K2 Acme y en L2 >12000

o En A3 ponga:

=BDSUMA(Ventas[#Todo] ; Ventas[[#Encabezados] ; [Importe]] ; G1:O2)

Page updated

Report abuse