NT. Nomenclatura de tablas.

Cuando convertimos un intervalo de datos (lista) en una tabla estamos definiendo una estructura para ese intervalo que facilitará su manejo. Entre otras ventajas:

Permite referenciar los datos (filas, columnas) de forma más clara. En lugar de utilizar notación de intervalo para referirnos a filas, columnas, etc. podremos utilizar nombres estructurados.
Los datos se actualizan automáticamente. Así, las funciones que utilizan nombres estructurados en lugar de intervalos no tendrán que ser actualizadas. Por ejemplo, tenemos la siguiente lista de datos.

Si queremos sumar la columna Alumnos utilizaríamos:

=SUMA(D2 : D16)

Si hemos convertido el intervalo en una tabla llamada Datos, utilizaremos:

=SUMA(Datos[Alumnos])

La notación de esta segunda forma es más clara. Además, si añadimos, por ejemplo, cinco nuevos registros y queremos actualizar las sumas, en la notación clásica de intervalo tendremos que modificar a =SUMA(D2:D20), mientras que en la notación tabla no será necesario ya que los nuevos datos se incorporan a la tabla y el cálculo de la función =SUMA(Datos[Importe]) se actualiza de forma automática.

Las columna que contienen fórmulas se expanden automáticamente al añadir nuevas filas de datos (registros).

NT.1 Tablas.

Vídeo: NT.1

Título: Tablas.

url: https://youtu.be/fjee8PdOe-4

Libro de trabajo: tabla_datos_1.xlsx

NT.1.1 Convertir un intervalo en una tabla.

Es aconsejable que la lista tenga una fila de encabezados con los nombres de cada columna.

Ejemplo NT.1.1-1

Convertir un intervalo en una tabla (intervalo definido).

Abra el libros de trabajo tabla_datos.xlsx de la carpeta ejercicios en Google Sheets. Recuerde subirlo antes.

- - - - Seleccione cualquier celda de la lista y convierta el intervalo en una tabla. Solo tiene que activar Formato / Convertir a tabla. La lista se convierte en una tabla que tendrá el aspecto siguiente:

Nota: Cuando Google Sheets detecta un intervalo de datos que puede convertirse en tabla mostrará en la parte inferior izquierda la siguiente opción, solo tiene que hacer clic sobre ella para convertir el intervalo en una tabla.

- - - - Cambie el nombre de la tabla. Solo tiene que desplegar la pestaña de la parte superior izquierda (su izquierda), habitualmente pondrá en nombre tabla_1, y activar la opción Cambiar nombre de tabla. Ponga el nombre Tabla.

NT.1.2 Definir / Cambiar el tipo de datos de cada columna.

Aunque no sea una operación necesario si resulta conveniente por claridad (y convención) aplicar a cada columna el tipo de datos correspondiente. Texto, Fecha y Numérica (tres opciones). Habitualmente Sheets ya define correctamente el tipo de datos de la columna.

Ejemplo NT.1.2-1

Definir el tipo de datos de las columnas de una tabla.

Sobre la tabla anterior, defina los siguientes tipos de columna. Solo tiene que desplegar la flecha que acompaña a la columna, Editar tipo de columna y escoger el tipo (A veces, al desplegar, tendrá que seleccionar Menú de columna / Editar tipo de columna).

Fecha: Tipo fecha.
Materia, Profesor y Tipo clase: Tipo texto.
Horas, Alumnos e Importe hora: Tipo Número / Número.

NT.2 Nomenclatura de tabla.

Función ARRAYFORMULA.

Vamos a ver las opciones que tenemos para referenciar diferentes elementos o partes de la tabla. Para ello tenemos que utilizar la función ARRAYFORMULA. Si viene de Excel la nomenclatura es muy parecida solo que en Excel es directo, no es necesario utilizar esta función.

Sintaxis de la función.

=ARRAYFORMULA(Notación)

Ejemplo NT.2-1

Ejemplos de nomenclatura tabla para referirse a datos, columnas, encabezados, celdas.

Abra el libro de trabajo tabla_datos.xlsx de la carpeta ejercicios. Si no ha realizado el ejemplo NT.1.1-1 hágalo ahora.

En el libro de trabajo Tabla_datos.xlsx. Cree una nueva hoja, póngale el nombre Referencias.

Vamos a ver las opciones que tenemos para referenciar diferentes elementos o partes de la tabla.

NT.2.1 Referenciar los datos de la tabla.

=Nombre_Tabla[#Data] o de forma abreviada =Nombre_Tabla

- - - - Vaya a celda A1 de la hoja Referencias y teclee

=ARRAYFORMULA(Tabla[#Data] ) o simplemente =ARRAYFORMULA(Tabla).

Nota: Observe que solo se devuelven los datos, sin los encabezados.

NT.2.2 Referenciar toda la tabla (encabezados y datos).

=Nombre_Tabla[#All]

- - - - Vaya a celda J1 de la hoja Referencias y teclee

=ARRAYFORMULA( Tabla[#All] )

NT.2.3 Referenciar nombres de campo o columna.

=Nombre_Tabla[#Headers]

- - - - Vaya a celda A20 de hoja Referencias y teclee

=ARRAYFORMULA( Tabla[#Headers] )

NT.2.4 Referenciar una columna (solo datos).

=Nombre_Tabla[Nombre_Columna]

- - - - Vaya a la celda J20 de hoja Referencias y teclee

=ARRAYFORMULA( Tabla[Materia] )

NT.2.5 Referenciar una columna (Encabezado y datos).

=Nombre_Tabla[[#All] ; [Nombre_Columna]]

- - - - Vaya a la celda L20 de hoja Referencias y teclee

=ARRAYFORMULA( Tabla[[#All] , [Materia]] )

NT.2.6 Referenciar columnas adjuntas (solo datos).

=Nombre_Tabla[[Nombre_Columna]:[Nombre_Columna]]

- - - - Vaya a la celda N20 de la hoja Referencias y teclee

=ARRAYFORMULA( Tabla[[Materia]:[Tipo clase]] )

NT.2.7 Referenciar columnas adjuntas (Encabezado y datos).

=Nombre_Tabla[[#All] , [Nombre_Columna] : [Nombre_Columna]]

- - - - Vaya a la celda S20 de la hoja Referencias y teclee

=ARRAYFORMULA( Tabla[[#ALL] , [Materia]:[Alumnos]] )

NT.2.8 Construir una columna calculada en una a la tabla.

Cuando crea una nueva columna adjunta a la tabla, ésta pasa a incorporarse a la tabla.

- - - Vaya a la celda H1 de la hoja Lista y teclee Importe. La columna se incorpora a la tabla.
    - En H2 ponga la fórmula siguiente.

=D2 * F2 * G2

- Confirme Autocompletar para expandir el cálculo al resto de celdas.

NT.2.9 Utilizar funciones con notación Tabla. Ejemplos.

- Vaya a la celda J1 de la hoja Lista y sume el Importe.

=SUMA(Tabla[Importe])

- - - - Vaya a la celda J2 de la hoja Listas y sume el Importe pero solo los la Materia Química.

=SUMAR.SI(Tabla[Materia] ; "Química" ; Tabla[Importe])

- - - - En J3, con la función BDSUMA sume el Importe de los registros cuyo Tipo clase sea Online y la cantidad de Alumnos > 10

- Defina los criterios de la forma siguiente (en hoja Lista)

- Y en J3

=BDSUMA( Tabla[#ALL] ; Tabla[[#HEADERS] , [Importe]] ; L1:M2 )

- - - - Añada este nuevo registro a la tabla, observe como el cálculo de las funciones se actualiza de forma automática